com, NewEnum and IUnknown

Hi

I'm basically wanting to intercept the For ... each mechanism to test
whether the object returned from the [_NewEnum] call fulfills a specific
criteria. If it does I want to return it, otherwise I want to recall the
[_NewEnum] until I either run out of objects or I find one with fulfills my
criteria

I'm finding that assigning an IUnknown to my own object definition is
generating a type mismatch. I thought all objects implemented IUnknown under
the hood.

Can I do it this way or will I have to implement a custom enumerator?

Here's my code


Public Property Get NewEnum() As IUnknown

Dim l_oUnknown As IUnknown
Dim l_oMyObject As CMyObject

Do
'm_cMyObjects is a VBA Collection of CMyObject
Set l_oUnknown = m_cMyObjects.[_NewEnum]

Set l_oMyObject = l_oUnknown <= generates a type mismatch

Loop While Not l_oMyObject.PassTest

Set NewEnum = l_oMyObject

End Property


Thanks

Simon

.[_NewEnum] returns a pointer to the IUnknown of an enumerator object
(an object of type IEnumVariant) which is the reason you're getting a
type mismatch.

For more detail about this whole process, you might want to have a
look at the collections stuff at http://www.mvps.org/vbvision

HTH,
Bryan
_______________________________
Bryan Stafford
New Vision Software
newvision_don' XXXX@XXXXX.COM


On Fri, 24 Feb 2006 17:07:27 -0000, "Simon Woods"

I don't think that's a good idea. It might be possible, but I can see it
being messy. Instead, let the code which is instigating the For..Each loop
check PassTest.

IOW...

Dim MyObject As CMyObject

For Each MyObject In MyObjectCollection
If MyObject.PassTest Then
'do whatever
End If
Next

That just seems to me to be a lot cleaner than what you're trying.

--
Mike
Microsoft MVP Visual Basic

NewEnum is only called once and returns the enumerator. To get each object
the Next method is called on the enumerator which is the method you will
need to override. So yes you will need a custom enumerator which is probably
possible in vb with the usual hacks.

Michael

Fair enough ... I didn't really want to expose the filtering of
MyObjectCollection as I didn't think the consumer needed to know anything
about it ... but perhaps, as you say, it is the cleanest way.

Thanks to all

Not necessarily, it doesn't look like it's too hard to achieve what you want
to achieve.

Michael

Really?

It struck me that adding an 'if' seemed certainly simpler than adding all
the custom enumerator stuff, and that's why I thought perhaps intervening in
the NewEnum may offer a half-way house. Perhaps it's the way I'm looking at
it since I've only done custom enumeration once before, I thought there'd be
a fair bit of learning curve for me. Please feel free to show me otherwise.

Thanks

Simon

"Simon Woods" < XXXX@XXXXX.COM > schrieb im



Here's an example of an IEnumVariant-Implementation:
(encapsulates a Recordset with a Lightweight-WrapperClass)
You can easily enhance this example with your own Filtering,
change the Data-Container from a Rs to a Collection, etc.
Simply debug this step by step and you will understand.

'****Into a Module
Private Declare Sub RtlMoveMemory Lib "kernel32" _
(Dest As Any, Src As Any, ByVal cb&)
Private Declare Function VariantCopy& Lib "oleaut32" _
(pvargDest, pvargSrc)

Public Type EnumVariant
vTable As Long
RefCount As Long
Index As Long
Parent As Object
End Type

Public Function SetEnum(E As EnumVariant, Parent, _
Optional StartIdx&) As IUnknown
Static IEnumVariant_vTable&(6)
E.vTable = VarPtr(IEnumVariant_vTable(0))
E.RefCount = 1: E.Index = StartIdx
Set E.Parent = Parent
RtlMoveMemory SetEnum, VarPtr(E), 4
If IEnumVariant_vTable(0) Then Exit Function
IEnumVariant_vTable(0) = AddrOf(AddressOf QueryInterface)
IEnumVariant_vTable(1) = AddrOf(AddressOf AddRef)
IEnumVariant_vTable(2) = AddrOf(AddressOf Release)
IEnumVariant_vTable(3) = AddrOf(AddressOf NextItem)
End Function

Private Function QueryInterface&(E As EnumVariant, riid&, lObj&)
E.RefCount = E.RefCount + 1
lObj = VarPtr(E)
End Function

Private Function AddRef&(E As EnumVariant)
E.RefCount = E.RefCount + 1
AddRef = E.RefCount
End Function

Private Function Release&(E As EnumVariant)
E.RefCount = E.RefCount - 1
Release = E.RefCount
If E.RefCount = 0 Then Set E.Parent = Nothing
End Function

Private Function NextItem&(E As EnumVariant, ByVal C&, V, ByVal pCFtch&)
Dim Idx&: Idx = E.Index
If Not E.Parent Is Nothing Then VariantCopy V, E.Parent.NewEnum(E.Index)
If E.Index = Idx Then NextItem = 1
End Function

Private Function AddrOf&(ByVal Addr&)
AddrOf = Addr
End Function

'*****Into a class CCustomerList
Public Rs As Object
Private Customer As New CCustomer

Public Function NewEnum(Optional Index&) '***Proc-Attr to (-4) !***
Static E As EnumVariant
'first call comes always from outside - we init only and then exit
If E.Parent Is Nothing Then Set NewEnum = SetEnum(E, Me): Exit Function

'this is the part called from inside our IEnumV-Impl. (the *.bas-Module)
'the Enumeration stops, if the index-param is not changed
Dim Fld
If Index = 0 Then Rs.MoveFirst
If Rs.EOF Then Exit Function 'means, the Index-Param stays unchanged
For Each Fld In Rs.Fields 'If Customer-PropNames = FieldNames
CallByName Customer, Fld.Name, VbLet, Fld.Value
Next
Set NewEnum = Customer
Rs.MoveNext
Index = Index + 1 'if we change the Index, then we are called again
End Function

'*****Into a class CCustomer
Public ID&, Name$

'*****Into a Testform
Private Sub Form_Click()
Dim C As CCustomer, CList As CCustomerList
Set CList = New CCustomerList
Set CList.Rs = CreateObject("adodb.Recordset")
CList.Rs.Fields.Append "ID", adInteger
CList.Rs.Fields.Append "Name", adVarWChar, 255
CList.Rs.Open
CList.Rs.AddNew Array("ID", "Name"), Array(1, "Name1")
CList.Rs.AddNew Array("ID", "Name"), Array(2, "Name2")
CList.Rs.AddNew Array("ID", "Name"), Array(3, "Name3")
For Each C In CList
Print C.ID, C.Name
Next
End Sub

Olaf

... such misplaced confidence in my abilities ;-)

Thanks very much Olaf- I shall certainly go through this.

Olaf

Well, it's working for me but I wonder if you can help a bit further as I
don't really fully understand. I really want to recursively call NewEnum
until a condition is met. Is it really just a question of incrementing the
index within the existing NewEnum function and calling NewEnum again?

Sorry if this seems a bit obvious!

Thanks

Simon

"Simon Woods" < XXXX@XXXXX.COM > schrieb im


Once a For Each-Loop is started (Calling 'NewEnum' once), you
cannot intercept it anymore from outside (excepting an 'Exit For' inside
the For-Each-Loop itself - but if I understand you correctly, this is,
what you want to avoid).
The Source I've posted cannot change this behaviour of For-Each,
but it would allow the skipping of elements of the DataContainer
*inside* the Class (be it an Array, a internal Collection or a Recordset)
- but only using Flags/Conditions, that you have to set inside the Class
*before* the For-Each-Loop is entered.
Not *you* have to call NewEnum explicitely - it is called implicitely
(triggered from the 'Next'-Call in the Outside-Loop) until you decide
(from a previously set Condition), that you want to exit the endless
Looping (by simply not changing the index anymore).

Yes - and no ;-) -> you don't have to call NewEnum yourself -
it is called automatically over and over again - you only have to
decide, when to stop.

But, if you describe, what you really want to achieve (filtering,
sorting, whatever and the DataContainer, that you want to use
inside your Class - be it an array or whatever), I will send you
an appropriate example, better addressing your scenario.

Olaf

Thanks I'm sorted

Simon

Yikes! :-)

Michael