moderated, (@_) = reverse(@_)

by **korovyev** » Tue, 11 Jan 2005 03:48:18 GMT

Hello,

sub swap { (@_) = reverse(@_); }
my $one = "I am one";
my $two = "I am two";
swap($one,$two);
warn "one is '$one'";
warn "two is '$two'";

The code above is a quote from Greg London's "Impationt Perl".
According to the book the output should be

> one is 'I am two'
> two is 'I am one'

The output I get (perl v5.8.6) is as follows:

> one is 'I am one'
> two is 'I am two'

How do you fix it?

by **Jean-Pierre Vidal** » Tue, 11 Jan 2005 05:45:01 GMT

Le Mon, 10 Jan 2005 11:48:18 -0800, Alexander Korovyev a rit?

($one,$two) = swap($one,$two);

but the following does the same

my $one = "I am one";
my $two = "I am two";
($one,$two) = ($two,$one);
warn "one is '$one'";
warn "two is '$two'";

JPV

by **Hans-Georg Rist** » Tue, 11 Jan 2005 06:49:04 GMT

The perlsub manual page tells (perl v5.8.4):

"Any arguments passed in show up in the array @_. Therefore, if you called a
function with two arguments, those would be stored in $_[0] and $_[1]. The
array @_ is a local array, but its elements are aliases for the actual
scalar parameters. In particular, if an element $_[0] is updated, the
corresponding argument is updated (or an error occurs if it is not
updatable). [...] Assigning to the whole array @_ removes that aliasing,
and does not update any arguments."

See the last sentence, that's what you did:
you assigned to the whole array @_.

Change your subroutine to:

sub swap {
( $_[0], $_[1] ) = reverse(@_);
}

and you'll notice the difference.

HTH,
HG

by **John W. Krahn** » Tue, 11 Jan 2005 08:00:57 GMT

What you are seeing is defined behaviour:

perldoc perlsub
[snip]
Any arguments passed in show up in the array @_. Therefore, if you
called a function with two arguments, those would be stored in $_[0]
and $_[1]. The array @_ is a local array, but its elements are aliases
for the actual scalar parameters. In particular, if an element $_[0]
is updated, the corresponding argument is updated (or an error occurs
if it is not updatable). If an argument is an array or hash element
which did not exist when the function was called, that element is
created only when (and if) it is modified or a reference to it is
taken. (Some earlier versions of Perl created the element whether or
not the element was assigned to.) Assigning to the whole array @_
^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^
removes that aliasing, and does not update any arguments.
^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^

The usual way to swap two values in perl is:

( $one, $two ) = ( $two, $one );

John
--
use Perl;
program
fulfillment

by **Brian McCauley** » Wed, 12 Jan 2005 02:25:46 GMT

Or, more generally:

sub swap {
@_[ 0 .. $#_ ] = reverse(@_);
}

moderated, (@_) = reverse(@_)

moderated >> (@_) = reverse(@_)

moderated >> (@_) = reverse(@_)

moderated >> (@_) = reverse(@_)

moderated >> (@_) = reverse(@_)

moderated >> (@_) = reverse(@_)